#include <amxmodx>
#include <oo>

#define main plugin_init

public oo_init()
{
  // 定义 Animal 类
  oo_class("Animal")
  {
      new cl[] = "Animal";

      oo_var(cl, "age", 1); // 为 Animal 定义变数 age 表示为这动物的年龄
      oo_var(cl, "name", 32); // 为 Animal 定义变数 name 表示为这动物的名字

      // 定义 Animal 的建构子得到名字和年龄的资料
      oo_ctor(cl, "Ctor", @str{name}, @int{age});

      // 定义 Animal 的解构子
      oo_dtor(cl, "Dtor");

      // 定义 MakeSound 方法 用以回传这动物的声音
      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      // 定义 GetLegs 方法 用以回传这动物有多少条腿
      oo_mthd(cl, "GetLegs");

      // 定义 Introduce 方法 输出这动物的自我介绍
      oo_mthd(cl, "Introduce");

      oo_smthd(cl, "Test"); // 静态方法测试
  }

  // 定义 Dog 类继承自 Animal 类
  oo_class("Dog", "Animal")
  {
      new cl[] = "Dog";

      // 定义建构子, 这会呼叫基类的建构子并输入 Dog 作为名字
      oo_ctor(cl, "Ctor", @int{age});

      // 取代原本的 MakeSound 方法 回传狗的叫声
      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      // 取代原本的 GetLegs 方法 回传狗有多少条腿
      oo_mthd(cl, "GetLegs");
  }

  // 定义 Cat 类继承自 Animal 类
  oo_class("Cat", "Animal")
  {
      new cl[] = "Cat";

      // 定义建构子, 这会呼叫基类的建构子并输入 Cat 作为名字
      oo_ctor(cl, "Ctor", @int{age});

      // 取代原本的 MakeSound 方法 回传猫的叫声
      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      // 取代原本的 GetLegs 方法 回传猫有多少条腿
      oo_mthd(cl, "GetLegs");
  }

  // 同上
  oo_class("Bird", "Animal")
  {
      new cl[] = "Bird";

      oo_ctor(cl, "Ctor", @int{age});

      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      oo_mthd(cl, "GetLegs");
  }

  // 同上
  oo_class("Snake", "Animal")
  {
      new cl[] = "Snake";

      oo_ctor(cl, "Ctor", @int{age});

      oo_mthd(cl, "MakeSound", @stref{msg}, @int{len});

      oo_mthd(cl, "GetLegs");
  }
}

// Animal 的建构子
public Animal@Ctor(const name[], age)
{
  new this = oo_this(); // 获取 this 物件的地址
  oo_set_str(this, "name", name); // 为动物的 name 变数赋以字串的值
  oo_set(this, "age", age); // 为动物的 age 变数赋以整数的值
}

// Animal 的解构子
public Animal@Dtor()
{
  new name[32];
  oo_get_str(oo_this(), "name", name, 32); // 获取这动物的 name 变数的字串值
  server_print("%s 已经被人道毁灭.", name);
}

public Animal@MakeSound(msg[], len)
{
  // format the message to the msg[]
  formatex(msg, len, "我是一个动物");
}

public Animal@GetLegs()
{
  return 0;
}

public Animal@Introduce()
{
  new this = oo_this();

  new name[32];
  oo_get_str(this, "name", name, 32);

  new age = oo_get(this, "age"); // 获取这动物的 age 变数的整数值

  new legs = oo_call(this, "GetLegs"); // 呼叫这动物的 GetLegs 方法, 获取动物的腿数量

  // 呼叫这动物的 MakeSound 方法 and retrieve the result to the msg[]
  new msg[64];
  oo_call(this, "MakeSound", msg, charsmax(msg));

  server_print("你好, 我的名字是 %s, 现在 %d 岁, 有 %d 条腿, 我会说 %s", name, age, legs, msg);
}

public Animal@Test() { server_print("静态方法测试"); }

public Dog@Ctor(age)
{
  // 呼叫父类 Animal 的建构子
  oo_super_ctor("Animal", "Dog", age);
}

public Dog@MakeSound(msg[], len)
{
  formatex(msg, len, "汪汪汪");
}

public Dog@GetLegs()
{
  return 4;
}

public Cat@Ctor(age)
{
  oo_super_ctor("Animal", "Cat", age);
}

public Cat@MakeSound(msg[], len)
{
  formatex(msg, len, "喵喵喵");
}

public Cat@GetLegs()
{
  return 4;
}

public Bird@Ctor(age)
{
  oo_super_ctor("Animal", "Bird", age);
}

public Bird@MakeSound(msg[], len)
{
  formatex(msg, len, "咕咕咕");
}

public Bird@GetLegs()
{
  return 2;
}

public Snake@Ctor(age)
{
  oo_super_ctor("Animal", "Snake", age);
}

public Snake@MakeSound(msg[], len)
{
  formatex(msg, len, "Sss sss");
}

public Snake@GetLegs()
{
  return 0;
}

public main()
{
  register_plugin("[OO] Animal", "0.1", "holla");

  // 建立物件
  new Animal:animals[5];
  animals[0] = oo_new("Dog", 7);
  animals[1] = oo_new("Cat", 6);
  animals[2] = oo_new("Bird", 4);
  animals[3] = oo_new("Snake", 3);
  animals[4] = oo_new("Animal", "Unknown", 0);

  for (new j = 0; j < 5; j++)
  {
      oo_call(animals[j], "Introduce"); // 为每一个物动呼叫自我介绍的方法
  }

     // Tests
     oo_call(0, "Animal@Test"); // Test calling the static method

     server_print("Object #%d %s a Snake", animals[3], oo_isa(animals[3], "Snake") ? "IS" : "IS NOT");
     server_print("Object #%d %s a Dog", animals[3], oo_isa(animals[3], "Dog") ? "IS" : "IS NOT");

     server_print("Class Dog %s a subclass of Animal", oo_subclass_of("Dog", "Animal") ? "IS" : "IS NOT");
     server_print("Class Animal %s a subclass of Cat", oo_subclass_of("Animal", "Cat") ? "IS" : "IS NOT");

     server_print("Class Bird %s", oo_class_exists("Bird") ? "EXISTS" : "DOES NOT EXIST");
     server_print("Class Fish %s", oo_class_exists("Fish") ? "EXISTS" : "DOES NOT EXIST");

     new class[32];
     oo_get_classname(animals[0], class, charsmax(class));
     server_print("Object #%d's classname is %s", animals[0], class);

     server_print("Object #%d %s", animals[0], oo_object_exists(animals[0]) ? "EXISTS" : "DOES NOT EXIST");

     for (new j = 0; j < 5; j++)
     {
           oo_delete(animals[j]); // Delete each animal objects
     }

     server_print("Object #%d %s", animals[0], oo_object_exists(animals[0]) ? "EXISTS" : "DOES NOT EXIST");
}

你好, 我的名字叫 Dog, 现在 7 岁, 我有 4 条腿, 我会说 汪汪汪
你好, 我的名字叫 Cat, 现在 6 岁, 我有 4 条腿, 我会说 喵喵喵
你好, 我的名字叫 Bird, 现在 4 岁, 我有 2 条腿, 我会说 咕咕咕
你好, 我的名字叫 Snake, 现在 3 岁, 我有 0 条腿, 我会说 Sss sss
你好, 我的名字叫 Unknown, 现在 0 岁, 我有 0 条腿, 我会说 我是一个动物
静态方法测试
Object #1943714116 IS a Snake
Object #1943714116 IS NOT a Dog
Class Dog IS a subclass of Animal
Class Animal IS NOT a subclass of Cat
Class Bird EXISTS
Class Fish DOES NOT EXIST
Object #461123433's classname is Dog
Object #461123433 EXISTS
Dog 已经被人道毁灭
Cat 已经被人道毁灭
Bird 已经被人道毁灭
Snake 已经被人道毁灭
Unknown 已经被人道毁灭
Object #461123433 DOES NOT EXIST